Late Favorite

Every parameter can be changed per squadron in the Control Tower without editing the script.

In the Control Tower, open Build a Viper and choose Community, then pick Late Favorite. The engine fetches it from this registry, checks the registry's signature, and shows the readme, parameters and source before anything is saved. It arrives switched off and on paper.

Or download the signed bundle file and use Import a viper file on the same page.

Don't run DRADIS yet? Launch it on AWS Marketplace in your own AWS account.

// Late favorite: in the last minutes of a crypto market, when the price sits
// well clear of the strike, buy the side it favors and hold it to settlement.
//
// The venue settles on its own index (Kalshi uses CF Benchmarks), not on the
// feed in ctx.oracle (Binance), and the two can differ by tens of dollars. The
// `basis` parameter is how far the feed reads ABOVE the settlement index; the
// distance to the strike is measured from the feed minus that. `min_fair`
// keeps it to real favorites rather than near-strike coin flips, and
// `fair_cap` limits how sure it may be (BTC's tails are fat).
fn entry(ctx) {
    if ctx.oracle == () || ctx.strike == () || ctx.secs_to_close == () {
        return #{ hold: "needs an oracle, a strike and a close time" };
    }
    let t = ctx.secs_to_close;
    if t > ctx.params.window_secs || t < 30 { return #{ hold: `outside the last ${ctx.params.window_secs}s` }; }

    // The price in the settlement's terms, and its distance to the strike in
    // standard deviations over the time left. The typical one-hour move is a
    // parameter (a fraction of the price), scaled by the square root of the
    // time left.
    let level = ctx.oracle - ctx.params.basis;
    let move_left = ctx.params.hourly_vol * level * (to_decimal(t) / 3600).sqrt();
    let z = (level - ctx.strike) / move_left;
    let p_yes = norm_cdf(z);
    let side = if p_yes > 0.5 { "yes" } else { "no" };
    let fair = if side == "yes" { p_yes } else { 1 - p_yes };
    // The normal curve's tails are too thin for BTC: cap the claim.
    if fair > ctx.params.fair_cap { fair = ctx.params.fair_cap; }
    if fair < ctx.params.min_fair { return #{ hold: `fair ${fair} below ${ctx.params.min_fair} (z ${z})` }; }

    let book = if side == "yes" { ctx.yes } else { ctx.no };
    if book.ask > ctx.params.max_price { return #{ hold: `ask ${book.ask} above ${ctx.params.max_price}` }; }
    let edge = fair - book.ask - taker_fee(book.ask);
    if edge < ctx.params.min_edge { return #{ hold: `edge ${edge} below ${ctx.params.min_edge}` }; }

    #{ buy: side, price: book.ask, shares: ctx.params.contracts,
       reason: `fair ${fair}, edge ${edge}, level ${level} vs strike ${ctx.strike}, z ${z}` }
}

// Held to the settlement: nothing to decide.
fn exit(ctx, pos) {
    ()
}

sha256 460e5bb7d803b988a09c327ddabd251258688fe87b162b1837f5b48e794bbc99

• 1.0.0 2026-11-09